TorchCS-MC/build.gradle

import torchcs.tasks.SetupMinecraft


layout.buildDirectory = file('build/gradle')

subprojects {
    layout.buildDirectory = rootProject.layout.projectDirectory.dir("build/gradle/${project.path.replace(':', '/').substring(1)}")

    repositories {
        mavenCentral()
    }

    plugins.withId('java') {
        sourceSets {
            main {
                java {
                    srcDirs = ['src']
                }
            }
        }
    }
}

tasks.register('setupMinecraft', SetupMinecraft) {
    group = 'torchcs'
    description = 'Sets up the Minecraft server environment'
}

tasks.register('configureNativeRelease', Exec) {
    commandLine 'cmake', '--preset', 'release'
}

tasks.register('buildNativeRelease', Exec) {
    group = 'torchcs'
    description = 'Configures and builds the native CMake targets (Release)'
    commandLine 'cmake', '--build', '--preset', 'release', '--parallel'
    dependsOn 'configureNativeRelease'
}

tasks.register('configureNativeDebug', Exec) {
    commandLine 'cmake', '--preset', 'debug'
}

tasks.register('buildNativeDebug', Exec) {
    group = 'torchcs'
    description = 'Configures and builds the native CMake targets (Debug)'
    commandLine 'cmake', '--build', '--preset', 'debug', '--parallel'
    dependsOn 'configureNativeDebug'
}

tasks.register('cleanNative', Delete) {
    group = 'torchcs'
    description = 'Deletes the native CMake build directory'
    delete 'build/cmake'
}